# Kapitel 19:  Umordnung von Reihen
# =========================
# Nach dem Riemannschen Umordnungssatz existiert zu einer bedingt
# konvergenten Reihe von reellen Zahlen und einer beliebig gegebenen
# reellen Zahl c stets eine Umordnung, die den Grenzwert c hat.
# Mit Maple kann man sich leicht von der G"ultigkeit dieses Satzes
# "uberzeugen. Letztlich kommt es bei einer Umordnung nur darauf an,
# wieviele positive und wieviele negative Terme in der jeweiligen
# Teilsumme stehen und nicht auf deren Reihenfolge innerhalb der
# Teilsumme. Dies nutzen wir aus, um verschiedene Umordnungen und
# Grenzwerte zu erzeugen, ohne eine explizite Indexfunktion  
# konstruieren zu m"ussen.
# Wir betrachten die alternierende harmonische Reihe
> Sum((-1)^k/k, k=1..infinity);
# Maple verwendet zur Darstellung der n-ten Teilsumme die 
# Digamma-Funktion Psi(n) :
> sum((-1)^k/k, k=1..n);
# Eine m"ogliche Definition von Psi(n) erh"alt man, wenn man die n-te
# Teilsumme der harmonischen Reihe berechnen l"asst:
> Sum(1/k, k=1..n) = sum(1/k, k=1..n);
# Dabei ist gamma die Eulersche Konstante mit der Eigenschaft:
> Limit((Sum(1/i, i=1..n) - ln(n)), n=infinity)= limit(sum(1/i, i=1..n)
> - ln(n), n=infinity);
# (Diese Klammersetzung ist unlogisch.)
# Daraus folgt f"ur das Verhalten von Psi(n) im Unendlichen:
> limit(Psi(n+1)-log(n), n=infinity);
# Wir betrachten nun eine Umordnung der alternierenden harmonischen
# Reihe, deren (n+n^2)-te Teilsumme die Gestalt p(n) hat mit
> p:=n->sum(1/(2*k), k=1..n) - sum(1/(2*k+1),k=0..n^2);
# Wir untersuchen lediglich den Grenzwert
> limit(p(n), n=infinity);
# und k"ummern uns nicht darum, wie die Teilsummen der Ordnung m mit
# n+n^2<m<(n+1)+(n+1)^2 aussehen. Im vorliegenden Fall gen"ugt die
# Divergenz einer Teilfolge zum Beweis, dass die Umordnung nicht
# konvergent ist. 
# =========================================
# Konvergente Umordnung mit vorgegebenem Grenzwert:
# 
# Bei den folgenden Umordnungen erhalten wir Konvergenz einer Teilfolge.
# Um daraus schliessen zu k"onnen, dass die Umordnung konvergiert,
# m"ussen wir uns davon 
# "uberzeugen, dass die Folge (s[m]) der m-ten Teilsummen eine
# Cauchyfolge ist. 
# Sei die Umordnung so gew"ahlt, dass die (n+1+[A n]) -te Teilsumme f"ur
# eine gegebene positive Zahl A die Gestalt p(n) hat (mit
# Gauss-Klammer[A n] :=  floor(A*n)) und
> p:=n->sum(1/(2*k),k=1..n)-sum(1/(2*k+1),k=0..floor(A*n));
# Dann gibt es verschiedene M"oglichkeiten, eine solche Umordnung zu
# realisieren. Wir betrachten die Teilsummen der Ordnung m=1,2,3,... mit
# n+[A n]+1 < m < n+2+[A (n+1)]. (Wenn A<1 ist, gibt es f"ur gewisse n
# kein solches m).
# Die beiden Extreme sind: Nach dem Auswerten von p(n) kommt zuerst der
# positive Summand 1/2(n+1), dann hat die Teilsumme s[m] der Ordnung
# m=n+[A n]+ den (gr"osstm"oglichen) Wert p(n)+1/2(n+1), oder es kommen
# zuerst alle negativen 
# Summanden -1/(2[An]+2+1), ... , -1/(2[A(n+1)]+1), dann hat die
# Teilsumme s[m] der Ordnung  m=n+1+[A (n+1)] den (kleinstm"oglichen)
# Wert p(n+1)-1/2(n+1). Alle Teilsummen s[m] mit n+[A n]+1 < m < n+2+[A
# (n+1)] f"ur jede m"ogliche Anordnung liegen zwischen diesen Werten.
# Deren Differenz ist 
> Differenz:=n->p(n)+1/(2*(n+1))-(p(n+1)-1/(2*(
> n+1)));
# und l"asst sich leicht nach oben durch 1/2(n+1)+A/(2[An]+3)
# absch"atzen. Da die Differenz f"ur n gegen Unendlich gegen Null
# konvergiert, ist die Folge s[m] eine Cauchy-Folge, falls die Folge
# (p(n)) konvergiert. 
# Letzteres kann man leider nicht direkt durch Maple nachpr"ufen lassen,
# da das "limit"-Programm anscheined nicht mit "floor" umgehen kann:
> assume(A>0);
> limit(Differenz(n), n=infinity);
# Auch "simplify" hilft hier nicht weiter.
# Das liegt nicht an der Psi--Funktion sondern an "floor":
> limit(Psi(floor(n))/n, n=infinity);
> limit(Psi(n)/n, n=infinity);
# Trotzdem l"asst sich mit Maple zeigen, dass
#  limit(Differenz(n),n=infinity = 0
# ist und
# limit(p(n),n=infinity = -ln(2)-ln(A)/2 .
# Dazu gehen wir davon aus, dass A*n-1 < floor(A*n)<= A*n  ist und somit
# aus der Definition von p(n) folgt `p-`(n)<=p(n) < `p+`(n) ,
# wobei die untere bzw. obere Absch"atzung gegeben ist durch
> `p-`:=n->sum(1/(2*k),
> k=1..n)-sum(1/(2*k+1),k=0..A*n);
> `p+`:=n->sum(1/(2*k),
> k=1..n)-sum(1/(2*k+1),k=0..A*n-1);
# Damit l"asst sich die Differenz nach oben und unten (man beachte, dass
# die Differenz negativ sein kann) absch"atzen durch
# `Differenz-`(n)<=Differenz(n) <=`Differenz+`(n)
# mit
> `Differenz+`:=n->`p+`(n)+1/(2*(n+1))-(`p-`(n+1)-1/(2*(n+1)));
> `Differenz-`:=n->`p-`(n)+1/(2*(n+1))-(`p+`(n+1)-1/(2*(n+1)));
# Diese Schrankenfunktionen konvergieren beide gegen Null:
> assume(A>0);
> limit(`Differenz+`(n), n=infinity);
> limit(`Differenz-`(n), n=infinity);
# Damit ist gezeigt, dass 
# limit(Differenz(n),n=infinity)=0
# ist. Also ist der Grenzwert der umgeordneten Reihe gleich dem
# Grenzwert der Teilfolge, d. h. gleich 
# limit(p(n),n=infinity)
# Diesen berechnen wir, indem wir die Grenzwerte von p+(n) und
# p-(n) bestimmen:
> limit(`p+`(n), n=infinity);
> limit(`p-`(n), n=infinity);
# Also hat die umgeordnete Reihe den Grenzwert
# -ln(n)-ln(A)/2 .
# 
# Hier ist unmittelbar abzulesen, wie A zu w"ahlen ist, um 
# eine vorgegebene reelle Zahl als Grenzwert zu erhalten. Zur 
# Kontrolle betrachten wir noch den Fall A=1:
> A:=1;
> p(n);
# Wir m"ussen noch die Annahme n=1,2,3,... eingeben, damit
# "floor" verschwindet:
> assume(n, posint); about(n);
> p(n);
# also  p(n)=sum((-1)^k/k,k=1..infinity)  ,
# und wir erhalten den bekannten Grenzwert:
> limit(p(n),n=infinity);